• 花山天文台
• 西田圭佑
• IDLメモ
• Direct Graphics

Direct Graphics

Window操作

• 新しく開く: window, n, xsize = width, ysize = height, retain = retain(nはwindow number、retainはグラフィックスの再描画をコントロール(0:再描画しない、1:Server/Systemが行う、2:IDLが行う))
• 閉じる: wdelete, n
• 操作対象を変更: wset, n
• 手前に表示する: wshow, n
• 背面に移動する: wshow, n, 0
• 最小化: wshow, n, /ICONIC
• 最小化したWindowを元に戻す: wshow, n, ICONIC = 0
• Windowに表示されてる内容を2次元配列に保存する: var = tvrd(x0, y0, width, height) (引数は省略可)。/trueを指定することで、24-bitカラーで保存できる([3, width, height] の3次元配列になる)。

グラフ

plot, y

普通にプロットする。(yは配列)

plot, x, y

xyプロット。(x, yは同サイズの配列)

plot, x, y, xrange = [0, 10], yrange = [-20, 30]

プロットエリアの範囲を指定する。

oplot

前の結果を消さずにプロットする。ただしxrange, yrangeなどは指定できない。

plot, x, y, psym = n

マーカーを指定する。nは-8～8および10。値が0か負の時はマーカーを結ぶ線を引き、正の値の時は線を引かない。8の時はユーザー指定のシンボルを書く(後述)。10の時はヒストグラムを書く。

plot, x, y, title = 'Graph Title', xtitle = 't', ytitle = 'R'

グラフ上部、x軸、y軸のタイトルを指定する。

plot, x, y, charsize = 1.2

文字サイズを変更する。(標準サイズを1.0とする)

plot, x, y, color = 255, background = 0, linestyle = 0

描画色・背景色・線種を指定する。

erase, color

色colorで画面消去する。(色を省略するとデフォルトの背景色 !p.background が用いられる)

tv, img, x, y

行列imgをイメージとして表示する。(imgの値は0～255に収まっている必要がある。imgは2次元配列)

tvscl, img, x, y

行列imgをイメージとして表示する。(自動的に0～255の範囲にスケーリングしてくれる)

contour, mまたはcontour, m, x, y

データ m の等高線を表示する。m を2次元配列、x, y を1次元配列で指定すると x[i]、y[j]での値が m[i, j] となり、非等方グリッド上のデータを表示できる。m, x, y を2次元配列で指定すると x[i, j]、y[i, j]での値が m[i, j] となり、直交座標系でないデータを表示できる。データ数が少ないときはmをmin_curve_surf(m)に置き換えると線がなめらかになる。fillキーワードで段彩図が書ける。irregularキーワードで非構造格子上のデータを表示できる。

分割

!p.multi = [0, 1, 2] (横1つ、縦2つ)

分割を元に戻す

!p.multi = 0

DEVICEやNORAMAL座標系で線・点を書く (oplot はDATA座標系でのみ利用可)

plots, x, y[, /DATA|, /DEVICE|, /NORMAL]

文字列を表示する

xyouts, x, y, '文字列'

グラフィックスの設定

• 色(color)の指定方法:
  • device, decomposed = 0としたとき: 8 bit の色番号を指定(0–255)。色番号と実際に表示される色の対応はカラーテーブルで決まる
  • device, decomposed = 1としたとき(デフォルト): 24 bit RGBカラーで指定
  • device, get_decomposed = result として、現在のカラーモードを取得できる
• カラーテーブルの詳細
• IDLのデフォルトのカラーテーブルの一覧
• 24 bit RGBカラーの指定方法 (device, decomposed = 1):
  • IDLでは24 bit RGBカラーを表現する形式は複数あり、プロシージャや機能ごとに指定方法が異なる。
  • 32 bit 整数は、plot, contour 等の多くのプロシージャでの色指定や !p.color, !p.background 等のシステム変数で用いられる
  • B * 65536 + G * 256 + R で計算される整数を指定する。B, G, R はそれぞれ青, 緑, 赤で0から255までの値。
  • 下位から8bitずつ赤、緑、青
  • 'ff0000'x または 0xff0000 (IDL 8.6.1以降) などと16進数で指定するとわかりやすい。(HTML等での色指定とはバイトの順番が逆になっていることに注意)
  • BYTE('FF8040'x, 0, 3) とすると、赤、緑、青 の値をそれぞれを取り出すことができる。
  • なお、Function Graphics の色指定では、バイトの順序がDirect Graphics と逆になる。(つまり、R * 65536 + G * 256 + B になる)
  • 赤、緑、青の値が順にそれぞれ異なる要素に格納されたbyte型の配列は tv, write_png, tvlct 等の画像やカラーテーブル操作等、多数の色を同時に扱うプロシージャで用いられる。
    • tv, tvrd で扱う配列の形状は TRUE = 1 で 3 x m x n、TRUE = 2 で m x 3 x n、TRUE = 3 で m x n x 3
    • write_png, write_jpeg で扱う配列の形状は 3 x m x n
    • tvlct で扱う配列の形状は 256 x 3 または長さ256の配列3個。
    • Graphic Function の IMAGE 関数は 3 x m x n、m x 3 x n、m x n x 3 を長さ3の次元があるかどうかで自動判別する。3 x 2 x 3 のように複数の次元の長さが3だと、最初の長さ3の次元が色を示すと解釈される。
    • Object graphics では、[赤, 緑, 青] の値が入った長さ3の配列で色を指定する。
    • 色を表すシステム定数 !color は赤, 緑, 青の値が入ったbyte型の配列で与えられる (help,!color,/struct)
• 線種(linestyle)の指定方法:

  番号	線種
  0	実線
  1	点線
  2	破線
  3	一点鎖線
  4	三点鎖線
  5	長い破線

• 線種(linestyle)の指定方法:

  番号	種類
  0	シンボルなしで点を結ぶ線を引く (デフォルト)
  1	+
  2	*
  3	.
  4	◇
  5	△
  6	□
  7	×
  8	ユーザー定義 ユーザー定義のシンボルを作成する例(塗りつぶした円): a = findgen(17) * (!pi*2/16.)&usersym, cos(a), sin(a), /fill
  10	ヒストグラムモード
  負の値 (-1～-8)	シンボルとそれを結ぶ線

• フォントの指定の例 (IDLのフォントの詳細):

  プログラム	結果
  (デフォルト) !p.font = -1 xyouts, '!3Hershey Vector Font 3, Simplex Roman', charsize=2
  !p.font = -1 xyouts, '!3Hershey Vector Font 3, Simplex Roman', charsize=2, charthick=2
  !p.font = -1 xyouts, '!4Hershey Vector Font 4, Simplex Greek', charsize=2
  !p.font = -1 xyouts, '!5Hershey Vector Font 5, Duplex Roman', charsize=2
  !p.font = -1 xyouts, '!9Hershey Vector Font 9, Math and Special', charsize=2
  !p.font = -1 xyouts, '!17Hershey Vector Font 17, Triplex Roman', charsize=2
  (TrueTypeフォントのデフォルト) !p.font = 1 device, set_font = 'Helvetica', /tt_font xyouts, 'TrueType Font 3, Helvetica', charsize=4
  !p.font = 1 device, set_font = 'Times', /tt_font xyouts, 'TrueType Font 7, Times', charsize=4
  !p.font = 1 device, set_font = 'Symbol', /tt_font xyouts, 'TrueType Font 9, Symbol', charsize=4
  !p.font = 1 device, set_font = 'DejaVuSans', /tt_font xyouts, 'TrueType Font 10, DejaVuSans', charsize=4
  !p.font = 1 device, set_font = 'Courier', /tt_font xyouts, 'TrueType Font 11, Courier', charsize=4

PSファイルに出力

• help, /device で現在の設定が表示される。
• xoffset, yoffset の値など、deviceプロシージャでの設定は保持されるので、次に別のプロットをする前にリセットしておく。
• A4の用紙(縦)にグラフを書く。デフォルトで portrait となる。xsize と ysize の単位は cm。DEVICE座標系で位置を指定するときの単位は 0.01mm。
  1. set_plot, 'ps'
  2. device, filename = 'test.ps', xsize = 21.0, ysize = 29.7, /portrait
  3. plot, cos(findgen(201) / 20 * !pi), title = 'Graph 1', position = [0.2, 0.3, 0.8, 0.7]
  4. plot, sin(findgen(201) / 20 * !pi), title = 'Graph 2', position = [2000, 2000, 6000, 6000], /device, /noerase
  5. device, /close_file
  6. set_plot, 'x' または set_plot, 'win'
  
• A4用紙を横向きに使う (landscape)。上下逆に出力される。yoffset の調整が必要。landscape では xoffset で上下方向、yoffset で左右方向のオフセットを変更する。
  1. device, filename = 'test.ps', xsize = 29.7, ysize = 21.0, xoffset = 0, yoffset = 29.7, /landscape
• EPS (Encapsulated PostScript) ファイルに出力する。
  1. device, filename = 'test.eps', xsize = 12, ysize = 10, /encapsulated
• カラーのEPSファイルを出力する。(256色 Indexed Color)
  1. set_plot, 'ps'
  2. device, filename = 'test.eps', xsize = 10, ysize = 10, /encapsulated, /color, decomposed = 0, bits_per_pixel = 8
  3. loadct, 3
  4. contour, dist(500), nlevels = 30, /fill
  5. device, /close_file
  
• カラーのEPSファイルを出力する。(Decomposed mode)
  1. set_plot, 'ps'
  2. device, filename = 'test.eps', xsize = 10, ysize = 10, /encapsulated, /color, decomposed = 1, bits_per_pixel = 8
  3. loadct, 49, rgb_table = color
  4. contour, dist(500), nlevels = 30, c_colors = (color[*, 0] + color[*, 1] * 256L + color[*, 2] * 65536L)[[0:29] / 29. * 255], /fill
  5. device, /close_file
  
• CMYKモードで出力する。左はCMYKモード、右はRGBモード(デフォルト)で出力した結果(をRGBのPNGに変換)。
  1. set_plot, 'ps'
  2. device, filename = 'test.eps', xsize = 10, ysize = 10, /encapsulated, /color, /cmyk, decomposed = 0, bits_per_pixel = 8
  3. color_convert, [[[[0:359] # replicate(1, 256)]], [[replicate(1, 360) # [0:255] / 255d]], [[replicate(1, 360, 256)]]], img, /hsv_rgb, interleave = 2
  4. tv, img, true = 3, xsize = 10000, ysize = 10000
  5. device, /close_file
  
• PostScriptフォントを指定する(IDLのフォントの詳細)。DEVICEプロシージャのキーワードで直接指定する方法、DEVICEプロシージャのSET_FONTキーワードでフォント名を指定する方法、Embedded Formatting Commandsを用いる方法がある。なお、具体的にどのフォントで表示されるかは、PSファイルを処理する環境に依存する(下記のサンプル画像でもNimbus Sansなどのメトリック互換書体で表示されている)。
  1. set_plot, 'ps'
  2. !p.font = 0
  3. device, filename = 'test.eps', xsize = 10, ysize = 10, /encapsulated, /helvetica
  4. xyouts, 0.1, 0.9, 'Helvetica'
  5. device, /helvetica, /bold
  6. xyouts, 0.1, 0.8, 'Helvetica-Bold'
  7. device, set_font = 'Helvetica-Oblique'
  8. xyouts, 0.1, 0.7, 'Helvetica-Oblique'
  9. device, set_font = 'Helvetica-BoldOblique'
  10. xyouts, 0.1, 0.6, 'Helvetica-BoldOblique'
  11. xyouts, 0.1, 0.5, '!7Times-Roman
  12. xyouts, 0.1, 0.4, '!11Courier
  13. xyouts, 0.1, 0.3, '!13Palatino-Roman
  14. xyouts, 0.1, 0.2, '!17AvantGarde-Book
  15. xyouts, 0.1, 0.1, '!18NewCenturySchlbk-Roman'
  16. device, /close_file